Validating Imported Data

// Count all node types
MATCH (n)
RETURN labels(n)[0] AS label, COUNT(*) AS count
ORDER BY label

// Verify Customer count (Expected: 91)
MATCH (c:Customer) RETURN COUNT(c) AS customerCount

// Verify Order count (Expected: 830)
MATCH (o:Order) RETURN COUNT(o) AS orderCount

// Verify Product count (Expected: 77)
MATCH (p:Product) RETURN COUNT(p) AS productCount

// Find orders without a customer relationship
MATCH (o:Order)
WHERE NOT (:Customer)-[:PLACED]->(o)
RETURN o.orderID AS orphanOrder
LIMIT 10

// Find products without a category
MATCH (p:Product)
WHERE NOT (p)-[:IN_CATEGORY]->(:Category)
RETURN p.productID, p.productName AS orphanProduct

// Find employees without a manager (should only be the CEO)
MATCH (e:Employee)
WHERE NOT (e)-[:REPORTS_TO]->(:Employee)
RETURN e.employeeID, e.firstName, e.lastName, e.title

// Verify orderDate is a date type, not a string
MATCH (o:Order)
WHERE o.orderDate IS NOT NULL
RETURN
    o.orderID,
    o.orderDate,
    apoc.meta.type(o.orderDate) AS dateType
LIMIT 5;

// Find customers where region might be empty string instead of missing
MATCH (c:Customer)
WHERE c.region = '' OR c.region = ' '
RETURN c.customerID, c.companyName, c.region

// Check that unitPrice is numeric
MATCH (p:Product)
RETURN
    p.productID,
    p.productName,
    p.unitPrice,
    apoc.meta.type(p.unitPrice) AS priceType
LIMIT 5;

MATCH (c:Customer {customerID: 'ALFKI'})
RETURN c.companyName, c.contactName, c.city, c.country

MATCH (c:Customer)-[:PLACED]->(o:Order {orderID: 10248})-[:CONTAINS]->(p:Product)
RETURN c.companyName, o.orderID, COUNT(p) AS itemCount