GraphAcademy

Cypher Fundamentals

Reading Data from Neo4j

Writing Data to Neo4j

Finding Relationships

Finding relationships

Our Goal

As a movie fanatic
I would like to find movies for a particular actor
So that I can watch a movie this evening

In the previous lesson, we used the MATCH clause to find the node in our database that represented Tom Hanks.

cypher
MATCH (p:Person {name: 'Tom Hanks'})
RETURN p

We can extend the pattern in the MATCH clause to traverse through all relationships with a type of ACTED_IN to any node. Our domain model shows that the ACTED_IN relationship goes in an outgoing direction from the Person node so we can add the direction in our pattern. We often refer to this as a traversal.

cypher
Incomplete code
MATCH (p:Person {name: 'Tom Hanks'})-[:ACTED_IN]->()

Our data model dictates that the node at the other end of that relationship will be Movie node, so we don’t necessarily need to specify the :Movie label in the node - instead we will use the variable m.

cypher
MATCH (p:Person {name: 'Tom Hanks'})-[:ACTED_IN]->(m)
RETURN m.title

This code returns the titles of all movies that Tom Hanks acted in.

If our graph had different labels, for example Television and Movie nodes this query would have returned all Television and Movie nodes that Tom Hanks acted in. That is, if we had multiple types of nodes at the end of the ACTED_IN relationships in our graph, we could make sure that we only return movies.

cypher
MATCH (p:Person {name: 'Tom Hanks'})-[:ACTED_IN]->(m:Movie)
RETURN m.title

Because our graph only has Movie nodes that have incoming ACTED_IN relationships, this query returns the exact same results as the previous query.

Check your understanding

1. Specifying the relationship direction

Say we wrote our query above differently and started with the Movie node. Use the dropdown below to select the correct direction for the query.

Once you have selected your option, click the Check Results query button to continue.

cypher
MATCH (m:Movie)/*select:<-[:ACTED_IN]-*/(p:Person)
RETURN m.title, p.name

  • ❏ -[:ACTED_IN]->

  • ✓ <-[:ACTED_IN]-

Hint

When you specify a direction for a relationship in a query, the query engine only looks for nodes that have that direction in their relationships when the relationship was created.

If you specify -[:ACTED_IN]- in the pattern, it doesn’t matter how the relationships are created in the graph.

How is the relationship defined between Person nodes and Movie nodes?

Solution

In our graph, the :ACTED_IN relationship always goes from a :Person node to a :Movie node.

As the :Movie node is defined as the first node in the pattern, the answer you are looking for is ←[:ACTED_IN]-.

2. Query using a pattern

Which MATCH clauses will return the names of the directors of the movie, The Matrix? (Select all that apply)

  • ✓ MATCH (m:Movie {title: 'The Matrix'})<-[:DIRECTED]-(p:Person) RETURN p.name

  • ❏ MATCH (m:Movie {title: 'The Matrix'})--(p:Person) RETURN p.name

  • ✓ MATCH (m:Movie {title: 'The Matrix'})<-[:DIRECTED]-(p) RETURN p.name

  • ❏ MATCH (m:Movie {title: 'The Matrix'})--(p:Director) RETURN p.name

Hint

The Person nodes represent people and the relationship must be DIRECTED.

You don’t necessarily need to define the :Person label for the node at the end of the pattern.

Solution

The two options below are valid options for finding the people who directed The Matrix:

MATCH (m:Movie {title: 'The Matrix'})←[:DIRECTED]-(p:Person) RETURN p.name
MATCH (m:Movie {title: 'The Matrix'})←[:DIRECTED]-(p) RETURN p.name

In the following query, you will technically get the directors but because the relationship type or direction type is not defined, you will receive all people connected to that movie, including anyone who acted in the movie through the :ACTED_IN relationship.

MATCH (m:Movie {title: 'The Matrix'})--(p:Person) RETURN p.name

The following query will return all :Person nodes with an outgoing :DIRECTED relationship, so it will include the directors of The Matrix, but also anyone related to the Matrix in either direction who have directed another movie.

MATCH (m:Movie {title: 'The Matrix'})--(p:Director) RETURN p.name

Summary

In this lesson, you learned how to traverse patterns in the graph with your queries using relationships. In the next challenge, you will demonstrate your skills for traversing the graph.