Merge Processing

Customizing MERGE behavior

You can also specify behavior at runtime that enables you to set properties when the node is created or when the node is found. We can use the ON CREATE SET or ON MATCH SET conditions, or the SET keywords to set any additional properties.

In this example, if the Person node for McKenna Grace does not exist, it is created and the createdAt property is set. If the node is found, then the updatedAt property is set. In both cases, the born property is set.

ON CREATE and ON MATCH Example

Run this Cypher code at least 2 times to observe what properties are set. You can see the properties in table view.

// Find or create a person with this name
MERGE (p:Person {name: 'McKenna Grace'})

// Only set the `createdAt` property if the node is created during this query
ON CREATE SET p.createdAt = datetime()

// Only set the `updatedAt` property if the node was created previously
ON MATCH SET p.updatedAt = datetime()

// Set the `born` property regardless
SET p.born = 2006

RETURN p

Setting multiple properties

If you want to set multiple properties for an ON CREATE SET or ON MATCH SET clause, you separate them by commas.

For example:

ON CREATE SET m.released = 2020, m.tagline = 'A great ride!'

Merging with relationships

You can use MERGE to create nodes or relationships:

Run this Cypher code:

// Find or create a person with this name
MERGE (p:Person {name: 'Michael Caine'})

// Find or create a movie with this title
MERGE (m:Movie {title: 'The Cider House Rules'})

// Find or create a relationship between the two nodes
MERGE (p)-[:ACTED_IN]->(m)

Single Clause MERGE with Relationships

Another way your can create these nodes and relationship is as follows:

MERGE (p:Person {name: 'Michael Caine'})-[:ACTED_IN]->(m:Movie {title: 'The Cider House Rules'})
RETURN p, m

Single Clause MERGE with Relationships Explained

Here is what happens in the query processor: